next up previous contents index
Next: Piecewise Linear Up: Tran Functions Previous: Pulse   Contents   Index

Gaussian Pulse

General Form:
gpulse(v1 v2 td pw per td1 td2 ... )
vsfq 0 0 gpulse(0 0 20p 2p 0 40p 60p)
vpulse 1 0 gpulse(0 1 100p 5p 100p)

parameter description default value units
v1 base value 0.0 volts or amps
v2 pulse peak value v1 volts or amps
td delay time 0.0 seconds
pw pulse width tstep seconds
per period 0.0 seconds

This generates a gaussian pulse signal, and as a special case, as a voltage source will generate single flux quantum (SFQ) pulses.

The expression used to generate a pulse is

value = v1 + (v2 - v1) . exp(- ((time - td )/pw)2)

The td delay value specifies the time of the initial pulse peak. The pw defines the pulse width, as evident in the expression. If the per is given a nonzero value larger than twice the pw, a train of pulses will be generated, the first being at td and at time increments of per thereafter. A per explicitly zero can be followed by any number of time values. A pulse will be generated to peak at each of these values, in addition to the td value.

If the amplitude is set to zero, i.e., v2 = v1, the amplitude will be computed from the pulse width to yield a single flux quantum pulse. Such a pulse, as a voltage applied across an inductor, will induce a single flux quantum of $ \Phi_{0}^{}$ = h/(2 . $ \pi$) = 2.06783fWb (h is Planck's constant, e is the electron charge). With superconductors, the flux that threads superconducting loops is quantized in increments of this value, due to the requirement that the superconducting wave function meet periodic boundary conditions around the loop. The computed amplitude is

v2 = v1 + $ \Phi_{0}^{}$/(pw . $ \sqrt{\pi}$)

where $ \Phi_{0}^{}$ is the flux quantum whose value is given above.

In superconducting electronics, single flux quantum pulses are generated and received by logic circuits. A generator of SFQ pulses is therefor a useful item when working with this technology.


* gaussian pulse

v1 1 0 gpulse(0 0 20p 2p 0 40p)
l1 1 2 10p
b1 2 0 100 jj3 area=.2
r2 2 0 2
.tran .1p 100p uic
.plot tran v(1) v(2) i(l1) ysep

* Nb 4500 A/cm2
.model jj3 jj(rtype=1, cct=1, icon=10m, vg=2.8m, delv=0.08m,
+ icrit=1m, r0=30, rn=1.7, cap=1.31p)

In the example, the generator produces two SFQ pulses. The second pulse causes the Josephson junction to emit a flux quantum, the second one from the source is therefor expelled. The inductor current shows the same value before and after the second pulse, as expected.

next up previous contents index
Next: Piecewise Linear Up: Tran Functions Previous: Pulse   Contents   Index
Stephen R. Whiteley 2017-11-08